add test textobjects queries for erlang,gleam,go,python,rust

runtime/queries/erlang/textobjects.scm

@@ -6,3 +6,11 @@
   (stab_clause body: (_) @function.inside)) @function.around
 
 (comment (comment_content) @comment.inside) @comment.around
+
+; EUnit test names.
+; (CommonTest cases are not recognizable by syntax alone.)
+((function_clause
+   name: (atom) @_name
+   pattern: (arguments (_)? @parameter.inside)
+   body: (_) @test.inside) @test.around
+ (#match? @_name "_test$"))

runtime/queries/gleam/textobjects.scm

@@ -4,3 +4,8 @@
 
 (anonymous_function
   body: (function_body) @function.inside) @function.around
+
+((function
+   name: (identifier) @_name
+   body: (function_body) @test.inside) @test.around
+ (#match? @_name "_test$"))

runtime/queries/go/textobjects.scm

@@ -26,3 +26,8 @@
 (comment) @comment.inside
 
 (comment)+ @comment.around
+
+((function_declaration
+   name: (identifier) @_name
+   body: (block)? @test.inside) @test.around
+ (#match? @_name "^Test"))

runtime/queries/python/textobjects.scm

@@ -16,3 +16,8 @@
 (comment) @comment.inside
 
 (comment)+ @comment.around
+
+((function_definition
+   name: (identifier) @_name
+   body: (block)? @test.inside) @test.around
+ (#match? @_name "^test_"))

runtime/queries/rust/textobjects.scm

@@ -77,3 +77,17 @@
 (line_comment)+ @comment.around
 
 (block_comment) @comment.around
+
+(; #[test]
+ (attribute_item
+   (meta_item
+     (identifier) @_test_attribute))
+ ; allow other attributes like #[should_panic] and comments
+ [
+   (attribute_item)
+   (line_comment)
+ ]*
+ ; the test function
+ (function_item
+   body: (_) @test.inside) @test.around
+ (#eq? @_test_attribute "test"))